Grand Task: Blazing Colosseum's notorious pits

[Captain Ventris]

Alright, some folks are aware that occasionally, a pit in blazing Colosseum will become double deep, or sometimes still hurt you after raising. That's because the scripts are weird:

script 85 open
{
 delay(random(595,3920));
 Floor_LowerInstant(1,0,12);
 ChangeFloor(1,"16_HEART");
 ACS_Execute(437,0,0,0,0);
 ACS_Terminate(441,0);
 delay(random(875,4200));
 Floor_RaiseInstant(1,0,12);
 ChangeFloor(1,"GRASS1_3");
 ACS_Terminate(437,0);
 ACS_Execute(441,0,0,0,0);
 restart;
}
script 86 open
{
 delay(random(595,3920));
 Floor_LowerInstant(2,0,12);
 ChangeFloor(2,"16_HEART");
 ACS_Execute(438,0,0,0,0);
 ACS_Terminate(442,0);
 delay(random(875,4200));
 Floor_RaiseInstant(2,0,12);
 ChangeFloor(2,"GRASS1_3");
 ACS_Terminate(438,0);
 ACS_Execute(442,0,0,0,0);
 restart;
}
script 87 open
{
 delay(random(595,3920));
 Floor_LowerInstant(3,0,12);
 ChangeFloor(3,"16_HEART");
 ACS_Execute(439,0,0,0,0);
 ACS_Terminate(443,0);
 delay(random(875,4200));
 Floor_RaiseInstant(3,0,12);
 ChangeFloor(3,"GRASS1_3");
 ACS_Terminate(439,0);
 ACS_Execute(443,0,0,0,0);
 restart;
}
script 88 open
{
 delay(random(595,3920));
 Floor_LowerInstant(4,0,12);
 ChangeFloor(4,"16_HEART");
 ACS_Execute(440,0,0,0,0);
 ACS_Terminate(444,0);
 delay(random(875,4200));
 Floor_RaiseInstant(4,0,12);
 ChangeFloor(4,"GRASS1_3");
 ACS_Terminate(440,0);
 ACS_Execute(444,0,0,0,0);
 restart;
}

script 437 (void)
{
 SectorDamage(1, random(20,30), "Annihilate", "null", DAMAGE_PLAYERS | DAMAGE_NONPLAYERS);
 delay(45);
 restart;
}
script 438 (void)
{
 SectorDamage(2, random(20,30), "Annihilate", "null", DAMAGE_PLAYERS | DAMAGE_NONPLAYERS);
 delay(45);
 restart;
}
script 439 (void)
{
 SectorDamage(3, random(20,30), "Annihilate", "null", DAMAGE_PLAYERS | DAMAGE_NONPLAYERS);
 delay(45);
 restart;
}
script 440 (void)
{
 SectorDamage(4, random(20,30), "Annihilate", "null", DAMAGE_PLAYERS | DAMAGE_NONPLAYERS);
 delay(45);
 restart;
}
script 441 (void)
{
 Sector_setDamage(1,0,14);
 delay(2);
}
script 442 (void)
{
 Sector_setDamage(2,0,14);
 delay(2);
}
script 443 (void)
{
 Sector_setDamage(3,0,14);
 delay(2);
}
script 444 (void)
{
 Sector_setDamage(4,0,14);
 delay(2);
}



The main problem is that it doesn't check if a floor is lowered or not, as far as I can tell.

Sooooooo, I'd really appreciate somebody rewriting the scripts to be more full-proof. Use the same sector tags and all, of course, and have the functionality stay the same, just... make it not do weird things. Thanks doods

[evilspacetomato]

This should work almost exactly the same give or take a half a second, and its much easier to read.


script 85 open
{
 //set dropping floors
 ACS_ExecuteAlways(86,0,1,0,0);
 ACS_ExecuteAlways(86,0,2,0,0);
 ACS_ExecuteAlways(86,0,3,0,0);
 ACS_ExecuteAlways(86,0,4,0,0);
}

script 86 (int Tag)
{
 //17-112 second wait
 delay(random(17,112) * 35);
 
 //floor is now lava
 Floor_LowerInstant(Tag, 0, 12);
 ChangeFloor(Tag, "16_HEART");
 
 //burn stuff
 int delayLoop = random(19,94);
 int i;
 for (i = 0; i < delayLoop; i++)
 {
   SectorDamage(Tag, random(20,30), "Annihilate", "null", DAMAGE_PLAYERS | DAMAGE_NONPLAYERS);
   delay(45);
 }
 
 //floor is not lava anymore
 Floor_RaiseInstant(Tag, 0, 12);
 ChangeFloor(Tag, "GRASS1_3");
 
 restart;
}


[Captain Ventris]

Does that randomly drop each section, or is it all at once?

[evilspacetomato]

It drops them separately like the other script,

script 85 creates four instances of script 86, one for each pit.

each of the four script 86s get told what pit they are and they wait, drop, hurt, raise and repeat.

It should work identically to the way the original was intended to work, and it is in a smaller easier to edit package.

[Captain Ventris]

...whoooooooa. Got it. Nice work, as always. Thanks a bunch!